; dxTextureBlend Example
; --------------------

dxGraphics3D 640,480
dxSetBuffer dxBackBuffer()

camera=dxCreateCamera()

; Choose a background colour which isn't the same colour as anything else, to  avoid confusion
dxCameraClsColor camera,255,0,0

light=dxCreateLight()
dxRotateEntity light,90,0,0

cube=dxCreateCube()
dxPositionEntity cube,0,0,5

; Load textures
tex0=dxLoadTexture( "media/b3dlogo.jpg" )
tex1=dxLoadTexture( "media/chorme-2.bmp" )

; Texture cube with textures
dxEntityTexture cube,tex0,0,0
dxEntityTexture cube,tex1,0,1

tex0_blend_info$="no texture"
tex1_blend_info$="no texture"

While Not dxKeyDown( 1 )

; Change texture 0 blending mode
If dxKeyHit( 11 )=True
tex0_blend=tex0_blend+1
If tex0_blend=4 Then tex0_blend=0
If tex0_blend=0 Then tex0_blend_info$="no texture"
If tex0_blend=1 Then tex0_blend_info$="no blend"
If tex0_blend=2 Then tex0_blend_info$="multiply"
If tex0_blend=3 Then tex0_blend_info$="add"
EndIf

; Change texture 1 blending mode
If dxKeyHit( 2 )=True
tex1_blend=tex1_blend+1
If tex1_blend=4 Then tex1_blend=0
If tex1_blend=0 Then tex1_blend_info$="no texture"
If tex1_blend=1 Then tex1_blend_info$="no blend"
If tex1_blend=2 Then tex1_blend_info$="multiply"
If tex1_blend=3 Then tex1_blend_info$="add"
EndIf

; Set texture blend modes
dxTextureBlend tex0,tex0_blend 
dxTextureBlend tex1,tex1_blend 

dxTurnEntity cube,0.1,0.1,0.1

dxRenderWorld

dxText 0,0,"Press 0 to change texture 0's blending mode"
dxText 0,20,"Press 1 to change texture 1's blending mode"
dxText 0,40,"dxTextureBlend tex0,"+tex0_blend+" ("+tex0_blend_info$+")"
dxText 0,60,"dxTextureBlend tex1,"+tex1_blend+" ("+tex1_blend_info$+")"

dxFlip

Wend

End